Formula Terbilang bagian 2 pada Gnumeric

• Buat terlebih dahulu pada kolom B dan C, sebuah tabel untuk proses LOOKUP angka-nya, sesuai dengan isi pada tabel di bawah ini:

Baris	Kolom B	Kolom C
1	0	-
2	1	satu
3	2	dua
4	3	tiga
5	4	empat
6	5	lima
7	6	enam
8	7	tujuh
9	8	delapan
10	9	sembilan

• Lalu isi kolom A dengan semua formula yang ada pada tabel di bawah ini

Sel	Isi	Contoh	Keterangan
A1	Sembarang angka	6,876,527,518,768.56	Nilai Inputan
A2	=text(A1,rept("0",15)&".00")	006876527518768.56	Format Teks "000,000,000,000,000,000.00"
A3	=left(A2,15)	006876527518768	Bagian 15 digit di depan koma
A4	=right(left(A3,len(A3)-12),3)	006	3 digit triliun
A5	=left(A4,1)	0
A6	=mid(A4,2,1)	0
A7	=right(A4,1)	6
A8	=right(left(A3,len(A3)-9),3)	876	3 digit milyar
A9	=left(A8,1)	8
A10	=mid(A8,2,1)	7
A11	=right(A8,1)	6
A12	=right(left(A3,len(A3)-6),3)	527	3 digit juta
A13	=left(A12,1)	5
A14	=mid(A12,2,1)	2
A15	=right(A12,1)	7
A16	=left(right(A3,6),3)	518	3 digit ribu
A17	=left(A16,1)	5
A18	=mid(A16,2,1)	1
A19	=right(A16,1)	8
A20	=right(A3,3)	768	3 digit satuan
A21	=left(A20,1)	7
A22	=mid(A20,2,1)	6
A23	=right(A20,1)	8
A24	=right(A2,2)	56	Bagian 2 digit di belakang koma
A25	=left(A24,1)	5
A26	=right(A24,1)	6
A27	=substitute(if(-(-A5)>0,lookup(-(-A5),$B$1:$B$10,$C$1:$C$10)&" ratus ",""),"satu ratus","seratus")		Konversi Trilyun1
A28	=substitute(if(-(-A6)>1,lookup(-(-A6),$B$1:$B$10,$C$1:$C$10)&" puluh ",if(and(-(-A6)=1,-(-A7)=0),lookup(-(-A6),$B$1:$B$10,$C$1:$C$10)&" puluh ","")),"satu puluh","sepuluh")		Konversi Trilyun2
A29	=if(and(-(-A6)=1,-(-A7)=0),"",if(and(-(-A6)=1,-(-A7)=1)," sebelas ",if(-(-A6)=1,lookup(-(-A7),$B$1:$B$10,$C$1:$C$10)&" belas ",lookup(-(-A7),$B$1:$B$10,$C$1:$C$10))))	enam	Konversi Trilyun3
A30	=substitute(if(-(-A9)>0,lookup(-(-A9),$B$1:$B$10,$C$1:$C$10)&" ratus ",""),"satu ratus","seratus")	delapan ratus	Konversi Milyar1
A31	=substitute(if(-(-A10)>1,lookup(-(-A10),$B$1:$B$10,$C$1:$C$10)&" puluh ",if(and(-(-A10)=1,-(-A11)=0),lookup(-(-A10),$B$1:$B$10,$C$1:$C$10)&" puluh ","")),"satu puluh","sepuluh")	tujuh puluh	Konversi Milyar2
A32	=if(and(-(-A10)=1,-(-A11)=0),"",if(and(-(-A10)=1,-(-A11)=1)," sebelas ",if(-(-A10)=1,lookup(-(-A11),$B$1:$B$10,$C$1:$C$10)&" belas ",lookup(-(-A11),$B$1:$B$10,$C$1:$C$10))))	enam	Konversi Milyar3
A33	=substitute(if(-(-A13)>0,lookup(-(-A13),$B$1:$B$10,$C$1:$C$10)&" ratus ",""),"satu ratus","seratus")	lima ratus	Konversi Juta1
A34	=substitute(if(-(-A14)>1,lookup(-(-A14),$B$1:$B$10,$C$1:$C$10)&" puluh ",if(and(-(-A14)=1,-(-A15)=0),lookup(-(-A14),$B$1:$B$10,$C$1:$C$10)&" puluh ","")),"satu puluh","sepuluh")	dua puluh	Konversi Juta2
A35	=if(and(-(-A14)=1,-(-A15)=0),"",if(and(-(-A14)=1,-(-A15)=1)," sebelas ",if(-(-A14)=1,lookup(-(-A15),$B$1:$B$10,$C$1:$C$10)&" belas ",lookup(-(-A15),$B$1:$B$10,$C$1:$C$10))))	tujuh	Konversi Juta3
A36	=substitute(if(-(-A17)>0,lookup(-(-A17),$B$1:$B$10,$C$1:$C$10)&" ratus ",""),"satu ratus","seratus")	lima ratus	Konversi Ribu1
A37	=substitute(if(-(-A18)>1,lookup(-(-A18),$B$1:$B$10,$C$1:$C$10)&" puluh ",if(and(-(-A18)=1,-(-A19)=0),lookup(-(-A18),$B$1:$B$10,$C$1:$C$10)&" puluh ","")),"satu puluh","sepuluh")		Konversi Ribu2
A38	=if(and(-(-A18)=1,-(-A19)=0),"",if(and(-(-A18)=1,-(-A19)=1)," sebelas ",if(-(-A18)=1,lookup(-(-A19),$B$1:$B$10,$C$1:$C$10)&" belas ",lookup(-(-A19),$B$1:$B$10,$C$1:$C$10))))	delapan belas	Konversi Ribu3
A39	=substitute(if(-(-A21)>0,lookup(-(-A21),$B$1:$B$10,$C$1:$C$10)&" ratus ",""),"satu ratus","seratus")	tujuh ratus	Konversi Satuan1
A40	=substitute(if(-(-A22)>1,lookup(-(-A22),$B$1:$B$10,$C$1:$C$10)&" puluh ",if(and(-(-A22)=1,-(-A23)=0),lookup(-(-A22),$B$1:$B$10,$C$1:$C$10)&" puluh ","")),"satu puluh","sepuluh")	enam puluh	Konversi Satuan2
A41	=if(and(-(-A22)=1,-(-A23)=0),"",if(and(-(-A22)=1,-(-A23)=1)," sebelas ",if(-(-A22)=1,lookup(-(-A23),$B$1:$B$10,$C$1:$C$10)&" belas ",lookup(-(-A23),$B$1:$B$10,$C$1:$C$10))))	delapan	Konversi Satuan3
A42	=substitute(if(-(-A25)>1,lookup(-(-A25),$B$1:$B$10,$C$1:$C$10)&" puluh ",if(and(-(-A25)=1,-(-A26)=0),lookup(-(-A25),$B$1:$B$10,$C$1:$C$10)&" puluh ","")),"satu puluh","sepuluh")	lima puluh	Konversi Pecahan1
A43	=if(and(-(-A25)=1,-(-A26)=0),"",if(and(-(-A25)=1,-(-A26)=1)," sebelas ",if(-(-A25)=1,lookup(-(-A26),$B$1:$B$10,$C$1:$C$10)&" belas ",lookup(-(-A26),$B$1:$B$10,$C$1:$C$10))))	enam	Konversi Pecahan2
A44	=if(-(-A5)+-(-A6)+-(-A7)>0,A27&A28&A29&" triliun ","")	enam triliun	Konversi Trilyun
A45	=if(-(-A9)+-(-A10)+-(-A11)>0,A30&A31&A32&" milyar ","")	delapan ratus tujuh puluh enam milyar	Konversi Milyar
A46	=if(-(-A13)+-(-A14)+-(-A15)>0,A33&A34&A35&" juta ","")	lima ratus dua puluh tujuh juta	Konversi Juta
A47	=if(-(-A16)=1," seribu ",if(-(-A17)+-(-A18)+-(-A19)>0,A36&A37&A38&" ribu ",""))	lima ratus delapan belas ribu	Konversi Ribu
A48	=if(-(-A21)+-(-A22)+-(-A23)>0,A39&A40&A41,"")	tujuh ratus enam puluh delapan	Konversi Satuan
A49	=substitute(if(-(-A25)+-(-A26)>0,A42&A43,""),"-","")	lima puluh enam	Konversi Pecahan
A50	=if(-(-A2)=0,"nol",if(-(-A24)=0,substitute(substitute(A44&A45&A46&A47&A48,"-","")," "," "),if(and(-(-A3)=0,-(-A24)>0),"nol koma "&substitute(substitute(A49,"- ","")," "," "),substitute(substitute(A44&A45&A46&A47&A48,"-","")," "," ")&" koma "&A49)))	enam triliun delapan ratus tujuh puluh enam milyar lima ratus dua puluh tujuh juta lima ratus delapan belas ribu tujuh ratus enam puluh delapan koma lima puluh enam	Terbilang - Final
A51	=if(-(-A2)=0,"nol rupiah",if(-(-A24)=0,substitute(substitute(A44&A45&A46&A47&A48,"-","")," "," ")&" rupiah",if(and(-(-A3)=0,-(-A24)>0),substitute(substitute(A49,"- ","")," "," ")&" sen",substitute(substitute(A44&A45&A46&A47&A48,"-","")," "," ")&" rupiah dan "&A49&" sen")))	enam triliun delapan ratus tujuh puluh enam milyar lima ratus dua puluh tujuh juta lima ratus delapan belas ribu tujuh ratus enam puluh delapan rupiah dan lima puluh enam sen	Terbilang - Rupiah

Pada saat proses penyalinan rumus / formula ke lembar kerja, biasanya diikuti dengan penambahan tanda kutip tunggal (untuk penanda teks), maka harap dibuang tanda kutip tersebut agar formula di atas dapat bekerja.

---

From Nothing to Nothing
10/3/2015

Formula Terbilang 1 pada Gnumeric

Untuk Nilai maksimal 999

• Jalankan aplikasi spreadsheet Gnumeric
• Pilih lembar kerja pada Sheet1 saja
• Misal Nilai yang ingin disebutkan angkanya berada pada sel A1
• Dan Hasilnya berada pada sel B1.
• Lalu buat Names melalui menu Edit > Modify > Names
• Klik tanda + pada bagian Sheet1 untuk menambahkan Names,

• Lalu ganti <New Name> dengan N dengan cara double-klik
• Dan disebelah kanan dari Name N diisi dengan (double-klik juga) :

{"Satu","Dua","Tiga","Empat","Lima","Enam","Tujuh","Delapan","Sembilan"}

• Setelah selesai menulis isinya, tekan [Enter], lalu Close untuk menutup jendela Define Names

• Pada sel B1, copy-paste formula berikut (buang tanda kutip tunggal di depan formula saat paste):

=if(-(-int(A1))=0,"Nol ",if(-(-(left(text(int(A1),"000"))))=1,"Seratus ",if(-(-(left(text(int(A1),"000"))))>1,index(N,1,-(-(left(text(int(A1),"000")))))&" Ratus ","")))&if(-(-(mid(text(int(A1),"000"),2,1)))=0,"",if(-(-(mid(text(int(A1),"000"),2,1)))=1,choose((-(-(right(text(int(A1),"0"))))=0)*1+((-(-(right(text(int(A1),"0"))))=1)*2)+((-(-(right(text(int(A1),"0"))))>1)*3),"Sepuluh ","Sebelas ",index(N,1,-(-(right(text(int(A1),"0")))))&"Belas "),if(-(-(mid(text(int(A1),"000"),2,1)))>1,index(N,1,-(-(mid(text(int(A1),"000"),2,1))))&" Puluh ")))&if(or(-(-(mid(text(int(A1),"000"),2,1)))=1,-(-(right(text(int(A1),"0"))))=0),"",index(N,1,-(-(right(text(int(A1),"0"))))))

Hasilnya seperti gambar berikut:

Untuk Nilai maksimal 999 Triliun

• Sama saja dengan yang di atas namun harus kita bagi per tiga-digit dari 15 digit bilangan
• Pastikan sudah terdapat Names N (untuk indexing) dengan isi sama seperti di atas yaitu:

{"Satu","Dua","Tiga","Empat","Lima","Enam","Tujuh","Delapan","Sembilan"}

• Isi pada input box formula untuk tiap sel seperti yang tertera pada tabel berikut (jangan lupa buang tanda kutip tunggal saat paste):

Sel	Formula / Nilai	Fungsi
A1	Isi dengan sembarang angka	Nilai Masukan
B1	=text(A1,rept("0",15))	Mengubah isi sel A1 menjadi teks berformat "000,000,000,000,000"
C1	=right(left($B1,len($B1)-12),3)	3 digit trilyun (teks)
D1	=right(left($B1,len($B1)-9),3)	3 digit milyar (teks)
E1	=right(left($B1,len($B1)-6),3)	3 digit juta (teks)
F1	=left(right($B1,6),3)	3 digit ribu (teks)
G1	=right($B1,3)	3 digit satuan (teks)
H1	=if(-(-int(C1))=0,"",if(-(-(left(text(int(C1),"000"))))=1,"Seratus ",if(-(-(left(text(int(C1),"000"))))>1,index(N,1,-(-(left(text(int(C1),"000")))))&" Ratus ","")))&if(-(-(mid(text(int(C1),"000"),2,1)))=0,"",if(-(-(mid(text(int(C1),"000"),2,1)))=1,choose((-(-(right(text(int(C1),"0"))))=0)*1+((-(-(right(text(int(C1),"0"))))=1)*2)+((-(-(right(text(int(C1),"0"))))>1)*3),"Sepuluh ","Sebelas ",index(N,1,-(-(right(text(int(C1),"0")))))&" Belas "),if(-(-(mid(text(int(C1),"000"),2,1)))>1,index(N,1,-(-(mid(text(int(C1),"000"),2,1))))&" Puluh ")))&if(or(-(-(mid(text(int(C1),"000"),2,1)))=1,-(-(right(text(int(C1),"0"))))=0),"",index(N,1,-(-(right(text(int(C1),"0"))))))	ubah nilai trilyun ke kata
I1	copy dari H1	ubah nilai milyar ke kata
J1	copy dari H1	ubah nilai juta ke kata
K1	copy dari H1	ubah nilai ribu ke kata
L1	copy dari H1	ubah nilai satuan ke kata
M1	=if(-(-int(A1))=0,"Nol",substitute(if(-(-C1)=0,"",H1&" Trilyun ")&if(-(-D1)=0,"",I1&" Milyar ")&if(-(-E1)=0,"",J1&" Juta ")&if(-(-F1)=0,"",if(-(-F1)=1," Seribu ",K1&" Ribu "))&if(-(-G1)=0,"",L1)," "," "))	Hasil Konversi

Hasilnya seperti contoh berikut:

Agar dapat digunakan pada Sheet lainnya, gunakan cara copy > paste special > paste link untuk Nilai inputan dan hasilnya

• Misal ada Sheet yang berisi satu sel, misal: D5 yang berisi angka yang akan kita ubah
• Maka kita copy isi sel D5, lalu pindah ke Sheet yang telah kita isi dengan formula di atas
• Klik kanan pada sel A1, Paste Special > Paste Link
• Setelah mendapatkan hasilnya pada sel M1, isi M1 di-copy lalu pindah ke Sheet sebelumnya
• Klik kanan pada sel untuk tempat hasilnya, misal D6, Klik kanan pada sel D6, Paste Special > Paste Link

Hasilnya adalah bila kita mengubah nilai pada sel D5, otomatis isi D6 juga ikut berubah, selama kedua sheet berada pada file yang sama.

Untuk nilai yang menggunakan sistem pecahan sen atau koma-komaan dapat dilihat pada bahasan terbilang bagian kedua.